;*********************************************************************
;*	
;*
;* File Name		: ADC_DEMO.ASM
;* Title		: Analog to Digital converter test
;* Date			: 07/04/99
;* Target MCU		: AT90S8535 or AT90S4433 on STK200
;* Coded By		: Tim Kuechler
;*
;*
;*
;* This program measures the voltage present at ADC0 on Analog port 
;* of STK200 Kit in terms of the ADC output.
;*
;* 	BUTTON FUNCTIONS:
;* 	 PD0 = Start measuring  (Default)
;*       PD1 = Stop measuring  
;* 	 PD2 = Show LSB of measurement Display LEDs On Solid (Default)
;*       PD3 = Show MSB of measurement Display LEDs Flashing
;*
;*       Data is displayed on LEDs of port B
;*
;* Psuedo code
;*
;*RESET:
;*
;*	INIT_STACK
;*	INIT_KEYS
;*	INIT_DISPLAY
;*	INIT_AD_CONV
;*	INIT_TIMER0  (flash rate)
;*
;*MAIN:
;*	IF [convert]	
;*		READ_VOLTS
;*	ENDIF
;*	DISPLAY_VOLTS
;*	KEYSCAN
;*	rjmp MAIN
;*
;*READ_VOLTS:
;*	SET_AD
;*	START_CONV
;*	IDLE 		Wait for conversion interrupt
;*	RETURN
;*
;*ADC:		Conversion interrupt
;*
;*
;*Things to watch on ADC:
;*1) ADSC stays high while conv is in progress
;*2) Always read from ADCL before ADCH.  This locks ADCH.
;*3) If ADC using noise canceller, make sure ADSC is low before entering IDLE state
;*4) ADMUX at I/O 0x07 ADCSR at I/O 0x06
;*5) INPORTANT: Writing a 1 to ADIF will CLEAR a pending ADC interrupt
;*This can happen on a Read-Modify-Write cycle even if that bit is not touched
;*For example a set bit to another bit in that register.
;*
;*
;*	STOP_CONV
;*	GET_VOLTS
;*	RETI
;*
;*DISPLAY_VOLTS:
;*	IF [FLSH_MOD]
;*		GET_MSB_VOLTS
;*	ELSE
;*		GET_LSB_VOLTS
;*	ENDIF
;*	AND FLSH_MSK           (If the display is supposed to be flashing, is it on or off?)
;*	OUTB
;*	RET
;*
;*KEYSCAN:
;*	IF [BUTTON 0]
;*		DEBOUNCE
;*		convert=1
;*	ENDIF
;*	IF [BUTTON 1]
;*		DEBOUNCE
;*		convert=0
;*	ENDIF
;*	IF [BUTTON 2]
;*		DEBOUNCE
;*		msb=false
;*	ENDIF
;*	IF [BUTTON 3]
;*		DEBOUNCE
;*		msb=true
;*	ENDIF
;*
;*
;*TIM0_OVF:
;*	DECR TIME
;*	IF [TIME=0]
;*		IF [FLSH_MSK & FLSH_MOD]
;*			FLSH_MSK=00
;*			TIME=SHORT
;*		ELSE	
;*			FLSH_MSK=FF
;*			TIME=LONG
;*		ENDIF
;*	ENDIF
;*	RESTART_TIMER
;*	RETI
;*
;*
;*
;*
;*
;*
;*
;*
;**********************************************************************
.include "8535def.inc"
;**************************** SET UP CONSTANTS ************************

.def	TEMP	= R16
.def	ITEMP	= R23

.def	SPEED   = R25
.def	UP_DOWN = R26		; 0 = UP, 1 = DOWN
.def	PGM     = R27		; 0=Count, 1=LPM, 2=PWM Auto, 3=PWM Man

.equ	EE_TST	= 0x0001	; E2 Test Location
.equ	EE_SPD	= 0x0002	; E2 SPEED Location
.equ	EE_UP	= 0x0003	; E2 UP_DOWN Location
.equ	EE_PGM	= 0x0004	; E2 PGM Location

;ADC INIT CONSTANTS

def	ADC_LO	= r20		;Storage location for raw A/D conversion result
.def	ADC_HI	= r21

.equ	ADC_CH0	= 0x00		; Select channel zero on ADC MUX
.equ	ADC_INI = 0b10000101	; ADEN=1, ADSC=0
				; ADFR=0, ADIF=0, ADIE=0 No interrupts yet please
				; Prescale = 101: 4MHZ/32 = 125KHz
.equ	ADC_COV = 1<<ADSC	; ADC start conversion flag (Init the ADC with DUMMY CONVERSION)
.equ	ADC_INT	= 1<<ADIE	; ADC Interrupt Enable Mask
;TIMER 0 INIT CONSTANTS

.equ	TC0_INI = 0x05          ; Prescale = 101: 4MHz/1024

;FLASHING DISPLAY CONSTANTS


.def	FLSH_TM = R17		;Flash off and on period counter (4MHZ/(1024*256) = 65ms per count)
;				;Values for FLSH_TM
.equ	FLSH_ON = 12		;12 * 65ms = approx 780ms  On time for flash
.equ	FLSH_OFF= 2		;OFF TIME = 130 MS

.def	FLSH_MSK= R18		;MASK for determining if LEDS are currently on or off
				;Values for FLSH_MSK
.equ	FLSH_INI= 0xFF		;Inititally, the LEDs should be in the ON part of the FLASH cycle
.equ	FLSH_BLK= 0x00		;Mask condition when the LEDs are suppoed to be blank.

def	FLSH_MOD= R19		;FLASH MODE Register: 0 = LSB of ADC is displayed and flashing is inactive
				;Values for FLSH_MOD
.equ	FLSH_MSB= 0xFF		;Show MSB of ADC and FLASH
.equ	FLSH_LSB= 0x00		;Show LSB of ADC and solid on

;MISC Program constants and flags

.def	CONVERT = R22		;Flag to show is ADC sampling is active (non zero is active)
.equ	SAMPLE	= 0x01		;Active
.equ	NO_SAMP = 0x00		;Inactive


;****************** Reset + Interrupt Vector Table ********************
.cseg
	rjmp	RESET		;RESET Vector
	rjmp	EXT_INT0	;External Interrupt 0 Vector
	rjmp	EXT_INT1	;External Interrupt 1 Vector
	rjmp	TIM2_COMP	;Timer2 Compare Handler
	rjmp	TIM2_OVF	;Timer2 Overflow Handler
	rjmp	TIM1_CAPT	;Timer/Counter1 Input Capture Vector
	rjmp	TIM1_COMPA	;T/C1 Compare Match A INT Vector
	rjmp	TIM1_COMPB	;T/C1 Compare Match B INT Vector
	rjmp	TIM1_OVF	;Timer/Counter1 Overflow INT Vector
	rjmp	TIM0_OVF	;Timer/Counter0 Overflow INT Vector
	rjmp	SPI_STC		;SPI Serial Transfer Complete Vector
	rjmp	UART_RXC	;UART Rx Complete Vector
	rjmp	UART_DRE	;UART Data Reg Empty Vector
	rjmp	UART_TXC	;UART Tx Complete Vector
	rjmp	ADC		;ADC Conversion Complete
	rjmp	EE_RDY		;EPROM Ready Handler
	rjmp	ANA_COMP	;Analog Comparator Match INT Vector

;*********************** INITIALIZE MICRO UPON RESET ******************
;**Design notes:
;*1) Change R16 to TEMP
;*2) Change any constants to names
;*
;*
;*	Pusedo CODE
;*
;*
;*	INIT_STACK
;*	INIT_DISPLAY
;*	INIT_KEYS
;*	INIT_AD_CONV
;*	DIS_ANACOMP
;*	INIT_TIMER0  (flash rate)
RESET:
	

	;INITIALIZE STACK POINTER

	ldi	TEMP,low(RAMEND)	
	out	SPL,TEMP	;Init Stack Pointer Low Byte
	ldi	TEMP,high(RAMEND)
	out	SPH,TEMP	;Init Stack Pointer High Byte


	;CONFIGURE LEDs (Display)

	ldi	TEMP,0xFF	;R16=FFh
	out	DDRB,TEMP	;PORTB = All Outputs (LED Display on STK 200)

	;CONFIGURE KEYS

	ldi	TEMP,0x00	;R16=00h
	out	DDRD,TEMP	;PORTD = All Inputs  (Buttons on STK 200)

	;CONFIGURE A/D CONVERTER

	ldi	CONVERT,SAMPLE	;Set Conversion MODE to sample
	
	ldi	TEMP,ADC_CH0	
	out	ADMUX,TEMP	;Select ADC Channel zero
	ldi	TEMP,ADC_INI|ADC_COV
	out	ADCSR,TEMP	;Perform one first conversion to init ADC
				;but do not generate an interrupt.

	;DISABLE ANALOG COMPARATOR to reduce noise and power consumption

	ldi	TEMP,1<<ACD	;Mask for AC disable bit
	out	ACSR,TEMP	;Set that bit in AC statu register

	;CONFIGURE DISPLAY FLASH TIMING and FLASH STATUS

	ldi	FLSH_TM,FLSH_ON	;Set Flash timer to ON part of duty cycle

				;Set Flash MASK to ON state
	ldi	FLSH_MSK,FLSH_INI	
				;Set Flash mode to SOLID, and display LSB of ADC
	ldi	FLSH_MOD,FLSH_LSB
					

	;CONFIGURE TIMER 0

	ldi	TEMP,TC0_INI	
	out	TCCR0,TEMP	;Select Timer0 CK/1024, start it running
	ldi	TEMP,1<<TOIE0	;Mask for Int Enable of Timer Overflow 0
	out	TIMSK,TEMP	;Enable the timer0 overflow interrupt in Timer Int Mask register

	sei			;Enable Global Interrupts



;****************************  MAIN PROGRAM  **************************
;*MAIN:
;*	IF [convert]	
;*		READ_VOLTS
;*	ENDIF
;*	DISPLAY_VOLTS
;*	KEYSCAN
;*	rjmp MAIN
;*
MAIN:
	cpi 	CONVERT,SAMPLE
	brne	NOSMP
	rcall	READ_VOLTS
NOSMP:	rcall	DISPLAY_VOLTS
	rcall	KEYSCAN
	rjmp	MAIN


;***************************  SUBROUTINES  ***************************

;*********************************************************************
;*READ_VOLTS:	
;*********************************************************************
;*Things to watch on ADC:
;*1) ADSC stays high while conv is in progress
;*2) Always read from ADCL before ADCH.  This locks ADCH.
;*3) If ADC using noise canceller, make sure ADSC is low before entering IDLE state
;*4) IMPORTANT: Writing a 1 to ADIF will CLEAR a pending ADC interrupt
;*This can happen on a Read-Modify-Write cycle even if that bit is not touched
;*For example a set bit to another bit in that register.

;Psuedo code
;*	CHECK_AD
;*	START_CONV
;*	IDLE 		Wait for conversion interrupt
;*	RETURN

READ_VOLTS:
	
	sbic	ADCSR,ADSC	;Poll ADC until it is idle
	rjmp	READ_VOLTS	;
	
	ldi	TEMP,ADC_INI|ADC_INT
	out	ADCSR,TEMP	;Enable ADC interrupt and perform conversion
				;upon entry to IDLE
	in	TEMP,MCUCR
	ori	TEMP,(1<<SE)	;Set SLEEP enable bit within MCUCR
	out	MCUCR,TEMP	;Enable SLEEP (Mode is IDLE by default)
	
	sleep
	ret

;*********************************************************************
;*DISPLAY_VOLTS
;*********************************************************************
;*	IF [FLSH_MOD]
;*		GET_MSB_VOLTS
;*	ELSE
;*		GET_LSB_VOLTS
;*	ENDIF
;*	AND FLSH_MSK (If the display is supposed to be flashing, is it on or off?)
;*	OUTB
;*	RET
DISPLAY_VOLTS:
	cpi	FLSH_MOD,FLSH_LSB	;Are we in display LSB Mode?
	breq	LSB			;
	mov	TEMP,ADC_HI		;We are in MSB Mode
	rjmp	VOLT
LSB:	mov	TEMP,ADC_LO		;Else are in LSB Mode
VOLT:	and	TEMP,FLSH_MSK		;Mask with the flashing mask
	com	TEMP			;LEDs are sinks, so complement output
	out	PORTB,TEMP
	ret
;*********************************************************************

;*********************************************************************
;*
;*	IF [BUTTON 0]
;*		DEBOUNCE
;*		convert=1
;*	ENDIF
;*	IF [BUTTON 1]
;*		DEBOUNCE
;*		convert=0
;*	ENDIF
;*	IF [BUTTON 2]
;*		DEBOUNCE
;*		msb=false
;*	ENDIF
;*	IF [BUTTON 3]
;*		DEBOUNCE
;*		msb=true
;*	ENDIF

KEYSCAN:sbis	PIND,0		;Is Button 0 Pressed?
	rjmp	STRCNV		;Yes! Start the conversion
	sbis	PIND,1		;Is Button 1 Pressed?
	rjmp	STPCNV		;Yes! Stop the conversion
	sbis	PIND,2		;Is Button 2 Pressed?
	rjmp	DSLSB		;Yes! Display LSB, on Solid
	sbis	PIND,3		;Is Button 3 Pressed?
	rjmp	DSMSB		;Yes! Display MSB, on flashing
	rjmp	DONE	

STRCNV: rcall	DELAY2		;Debounce
	sbis	PIND,0		;Is Button 0 Released
	rjmp	STRCNV		;No! Wait More
	ldi	CONVERT,SAMPLE	;Set conversion mode to SAMPLE
	rjmp	DONE	
STPCNV: rcall	DELAY2		;Debounce
	sbis	PIND,1		;Is Button 1 Released
	rjmp	STPCNV		;No! Wait More
	ldi	CONVERT,NO_SAMP	;Set conversion mode to NO_SAMPLE
	rjmp	DONE	
DSLSB:	rcall	DELAY2		;Debounce
	sbis	PIND,2		;Is Button 2 Released
	rjmp	DSLSB		;No! Wait More
	ldi	FLSH_MOD,FLSH_LSB ;Set display mode to LSB, no flash
	rjmp	DONE		;
DSMSB:	rcall	DELAY2		;Debounce
	sbis	PIND,3		;Is Button 3 Released
	rjmp	DSMSB		;No! Wait More
	ldi	FLSH_MOD,FLSH_MSB ;Set display mode to MSB,flash
	rjmp	DONE		;
DONE:	ret

DELAY2:	ldi	TEMP,0xFF	;Debounce Delay Subroutine
D2:	dec	TEMP
	brne	D2
	ret

;*********************  INTERRUPT SERVICE ROUTINES  *******************
;DO NOT use Register TEMP in these routines

EXT_INT0:		;External Interrupt 0 Service Routine
	reti
EXT_INT1:		;External Interrupt 1 Service Routine
	reti
TIM2_COMP:		;Timer2 Compare Handler
	reti
TIM2_OVF:		;Timer2 Overflow Handler
	reti
TIM1_CAPT:		;Timer/Counter1 Input Capture Routine
	reti
TIM1_COMPA:		;T/C1 Compare Match A INT Service Routine
	reti
TIM1_COMPB:		;T/C1 Compare Match B INT Service Routine
	reti
TIM1_OVF:		;Timer/Counter1 Overflow INT Service Routine
	reti
;*********************************************************************
TIM0_OVF:		;Timer/Counter0 Overflow INT Service Routine
;*********************************************************************
;*	Psuedo code
;*	DECR TIME
;*	IF [TIME=0]
;*		IF [(FLSH_MSK = FLSH_INI) & (FLSH_MOD = FLSH_MSB)]
;*			FLSH_MSK=FLSH_BLK
;*			TIME=SHORT
;*		ELSE	
;*			FLSH_MSK=FLSH_INI
;*			TIME=LONG
;*		ENDIF
;*	ENDIF
;*	RETI

	in	ITEMP,SREG	
	push	ITEMP			;preserve statues register
	dec	FLSH_TM			;Tick on the Flash timer
	brne	FLSH_NC			;No Change unless timer has expired
	cpi	FLSH_MOD,FLSH_MSB 	;If MODE is not MSB
	brne	FLSH_LN			;then Flash mask s/b ON
	cpi	FLSH_MSK,FLSH_INI	;If Flash mask is ON (and MODE is MSB)
	brne	FLSH_LN			;then FLASH SHORT, else FLSH_LN
FLSH_SHRT:
	ldi	FLSH_MSK,FLSH_BLK	;Set FLASH mask to BLANK state
	ldi	FLSH_TM,FLSH_OFF	;Set OFF time to timer
	rjmp	FLSH_NC			;else
FLSH_LN:
	ldi	FLSH_MSK,FLSH_INI	;Set FLASH mask to ON state
	ldi	FLSH_TM,FLSH_ON		;Set ON time to timer
					;endif
FLSH_NC:
	POP	ITEMP
	OUT	SREG,ITEMP		;restore status register
	reti
;*********************************************************************


	reti

SPI_STC:		;SPI Serial Transfer Complete Service Routine
	reti
UART_RXC:		;UART Rx Complete Service Routine
	reti
UART_DRE:		;UART Data Reg Empty Service Routine
	reti
UART_TXC:		;UART Tx Complete Service Routine
	reti
;*********************************************************************
ADC:			;ADC Conversion Complete Handler
;*********************************************************************
;*
;*
;*
;*Things to watch on ADC:
;*1) ADSC stays high while conv is in progress
;*2) Always read from ADCL before ADCH.  This locks ADCH.
;*3) If ADC using noise canceller, make sure ADSC is low before entering IDLE state
;*4) ADMUX at I/O 0x07 ADCSR at I/O 0x06
;*5) INPORTANT: Writing a 1 to ADIF will CLEAR a pending ADC interrupt
;*This can happen on a Read-Modify-Write cycle even if that bit is not touched
;*For example a set bit to another bit in that register.
;*
;*Psuedo code		
;*	STOP_CONV
;*	GET_VOLTS
;*	RETI

	in	ITEMP,MCUCR	;Get control register
	andi	ITEMP,0xFF^(1<<SE)	;Clear the Sleep Enable bit
	out	MCUCR,ITEMP	;Use ITEMP instead of TEMP 'cause in an ISR
	in	ADC_LO,ADCL	;Preserve the result of the latest conversion
	in	ADC_HI,ADCH
	reti
;*********************************************************************

EE_RDY:			;EEPROM Ready Handler
	reti
ANA_COMP:		;Analog Comparator Match INT Service Routine
	reti

;***************************  LOOK UP TABLES **************************
EXTRA:	nop
LUT1:
	.db	0x7E,0xBD	; 0111 1110 , 1011 1101
	.db	0xDB,0xE7	; 1101 1011 , 1110 0111
	.db	0xDB,0xBD	; 1101 1011 , 1011 1101

.exit